use_tuis = true
if is_windows
  use_tuis = false
endif

if use_tuis and (get_option('server').enabled() or get_option('client').enabled())
  notcurses = dependency('notcurses', required: false, allow_fallback: false)
  notcurses_core = dependency('notcurses-core', required: false, allow_fallback: false)
  if not notcurses.found() or not notcurses_core.found()
    notcurses_opts = cmake.subproject_options()
    notcurses_opts.add_cmake_defines({ 'CMAKE_BUILD_TYPE': is_debug ? 'Debug' : 'Release' })
    notcurses_opts.add_cmake_defines({ 'USE_CXX': false })
    notcurses_opts.add_cmake_defines({ 'USE_DEFLATE': false })
    notcurses_opts.add_cmake_defines({ 'USE_DOCTEST': false })
    notcurses_opts.add_cmake_defines({ 'USE_PANDOC': false })
    notcurses_opts.add_cmake_defines({ 'BUILD_EXECUTABLES': false })
    notcurses_opts.add_cmake_defines({ 'BUILD_FFI_LIBRARY': false })
    notcurses_opts.add_cmake_defines({ 'USE_POC': false })
    notcurses_opts.add_cmake_defines({ 'USE_STATIC': true })
    notcurses_opts.add_cmake_defines({ 'USE_MULTIMEDIA': is_windows ? 'none' : 'ffmpeg' })
    notcurses_proj = cmake.subproject('notcurses', options: notcurses_opts)
    if is_windows
      notcurses = notcurses_proj.dependency('notcurses-static')
      notcurses_core = notcurses_proj.dependency('notcurses-core-static')
    else
      notcurses = notcurses_proj.dependency('notcurses')
      notcurses_core = notcurses_proj.dependency('notcurses-core')
    endif
  endif
endif

if get_option('server').enabled() and not is_windows
  subdir('cmsrv')
endif

if get_option('client').enabled() and not is_windows
  subdir('cmc')
endif

if get_option('sink').enabled()
  if is_android
    subdir('ctv')
  else
    subdir('cmv')
  endif
endif